# Option fully deprecated, it warns when any value is set.
option('o1', type: 'boolean', deprecated: true)

# One of the choices is deprecated, it warns only when 'a' is in the list of values.
option('o2', type: 'array', choices: ['a', 'b'], deprecated: ['a'])

# One of the choices is deprecated, it warns only when 'a' is in the list of values
# and replace it by 'c'.
option('o3', type: 'array', choices: ['a', 'b', 'c'], deprecated: {'a': 'c'})

# A boolean option has been replaced by a feature, old true/false values are remapped.
option(
    'o4',
    type: 'feature',
    deprecated: {'true': 'enabled', 'false': 'disabled'},
)

# A feature option has been replaced by a boolean, enabled/disabled/auto values are remapped.
option(
    'o5',
    type: 'boolean',
    deprecated: {'enabled': 'true', 'disabled': 'false', 'auto': 'false'},
)

# A boolean option has been replaced by a feature with another name, old true/false values
# are accepted by the new option for backward compatibility.
option('o6', type: 'boolean', value: true, deprecated: 'o7')
option(
    'o7',
    type: 'feature',
    value: 'enabled',
    deprecated: {'true': 'enabled', 'false': 'disabled'},
)

# A project option is replaced by a module option
option('o8', type: 'string', value: '', deprecated: 'python_platlibdir')

# different than meson: python.platlibdir is not an option
option('python_platlibdir', type: 'string')
